feat: ship an Inno Setup installer from the windows release job

windows/carrier.iss

@@ -0,0 +1,42 @@
+; carrier Windows installer. Packs the same portable bundle windows/
+; bundle.sh produces (dist/) into a classic setup.exe: Program Files,
+; Start Menu shortcut, optional desktop icon, Apps & Features uninstall
+; entry. Built by windows/installer.sh, which passes /DVersion= from
+; Cargo.toml.
+;
+; Not yet wired into the forgejo release job - deliberately local until
+; the experience is signed off.
+
+#ifndef Version
+  #error Pass the version: ISCC /DVersion=0.2.0 windows/carrier.iss
+#endif
+
+[Setup]
+AppId={{345BADA4-146B-4F57-B7D3-E9FD5D664F4B}
+AppName=carrier
+AppVersion={#Version}
+AppPublisher=randogoth
+DefaultDirName={autopf}\carrier
+DefaultGroupName=carrier
+; Next to the portable zip (paths relative to this script's directory).
+OutputDir=..
+OutputBaseFilename=carrier-windows-{#Version}-setup
+Compression=lzma2/max
+SolidCompression=yes
+WizardStyle=modern
+ArchitecturesInstallIn64BitMode=x64compatible
+UninstallDisplayName=carrier
+
+[Tasks]
+Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
+
+[Files]
+Source: "..\dist\*"; DestDir: "{app}"; Flags: recursesubdirs createallsubdirs ignoreversion
+
+[Icons]
+; Shortcut icons come from carrier.exe's embedded .ico resource.
+Name: "{group}\carrier"; Filename: "{app}\carrier.exe"
+Name: "{autodesktop}\carrier"; Filename: "{app}\carrier.exe"; Tasks: desktopicon
+
+[Run]
+Filename: "{app}\carrier.exe"; Description: "Launch carrier"; Flags: nowait postinstall skipifsilent